Menú de arreglo numérico
〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
Algoritmo Menu_de_Arreglo
//Elaborado por:Leonardo Cabezas Briones
Dimension num[10]
Definir num Como Entero
Definir opcMenu Como Entero
Definir salir Como Logico
Mientras !(salir)
Escribir"Bienvenido a el menu de Arreglo numerico "
Escribir ""
Escribir ""
Escribir ""
Esperar 2 Segundos
Escribir "------------------------------------------"
Escribir " MENU"
Escribir "------------------------------------------"
Escribir "(1) 10 valores en arreglo por teclado"
Escribir "------------------------------------------"
Escribir "(2) Ordenar arreglo de menor a mayor"
Escribir "------------------------------------------"
Escribir "(3) ¿Es primo el menor número del arreglo"
Escribir "------------------------------------------"
Escribir "(4) Suma de los 10 números del arreglo"
Escribir "------------------------------------------"
Escribir "(5) El mayor, ¿es par o impar?"
Escribir "------------------------------------------"
Escribir "(6) Resta entre el mayor y el menor"
Escribir "------------------------------------------"
Escribir "(7) Salir"
Escribir "------------------------------------------"
Escribir "Elija una opción del 1 al 7...." Sin Saltar
Leer opcMenu
Borrar Pantalla
Segun opcMenu Hacer
1:
valores(num)
teclayBorrar
2:
ordenar(num,10)
mostrarArreglo(num,10)
teclayBorrar
3:
ordenar(num,10)
Si esPrimo(num[1]) Entonces
Escribir "El número menor ", num[1], " es primo"
SiNo
Escribir "El número menor ", num[1], " no es primo"
FinSi
teclayBorrar
4:
Escribir "Los 10 números suman ", sumaArreglo(num,10)
Escribir ""
teclayBorrar
5:
ordenar(num,10)
Si esPar(num[10]) Entonces
Escribir "El número mayor ", num[10], " es par"
SiNo
Escribir "El número mayor ", num[10], " es impar"
FinSi
teclayBorrar
6:
ordenar(num,10)
Escribir "La resta entre el mayor y el menor es: ", num[10], " - ", num[1], " = ", num[10]-num[1]
teclayBorrar
7:
salir <- Verdadero
FinSegun
FinMientras
FinAlgoritmo
Funcion valores(arreglo Por Referencia)
Definir i Como Entero
i<-1
Repetir
Escribir "Número ", i, ": " Sin Saltar
Leer arreglo[i]
Si !(arreglo[i]>50 Y arreglo[i]<=100) Entonces
Escribir "El número tiene que ser mayor de 50 y menor o igual que 100"
Escribir "Inténtelo de nuevo"
SiNo
i<-i+1
FinSi
Hasta Que (i>10)
FinFuncion
Funcion ordenar(arreglo Por Referencia, elementos)
// Ordenación por selección en orden creciente
Definir i, j, min Como Entero
Definir temp Como Numero
Para i<-1 Hasta (elementos-1) Con Paso 1
min<-i
j<-i+1
Mientras (j<=elementos) Hacer
Si arreglo[j] < arreglo[min] Entonces
min<-j
FinSi
j<-j+1
FinMientras
temp<-arreglo[i]
arreglo[i]<-arreglo[min]
arreglo[min]<-temp
FinPara
FinFuncion
Funcion mostrarArreglo(arreglo, elementos)
Definir i Como Entero
Para i<-1 Hasta elementos Con Paso 1 Hacer
Escribir arreglo[i], " " Sin Saltar
FinPara
Escribir ""
FinFuncion
Funcion OK <- esPrimo(n)
Definir i,esDivisible Como Entero
Definir OK Como Logico
Para i<-1 Hasta n Hacer
Si n>=1 Entonces
Si (n MOD i==0) Entonces
esDivisible <- esDivisible+1
FinSi
FinSi
FinPara
Si (esDivisible==2) Entonces
OK <- Verdadero
SiNo
OK <- Falso
FinSi
FinFuncion
Funcion S <- sumaArreglo(arreglo, elementos)
Definir i, S Como Entero
S <- 0
Para i<-1 Hasta elementos Con Paso 1 Hacer
S <- S + arreglo[i]
FinPara
FinFuncion
Funcion OK <- esPar(n)
Definir OK Como Logico
Si (n MOD 2==0) Entonces
OK <- Verdadero
SiNo
OK <- Falso
FinSi
FinFuncion
Funcion teclayBorrar
Escribir "Pulse una tecla para continuar...."
Esperar Tecla
Borrar Pantalla
〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
No hay comentarios:
Publicar un comentario